2d3d/3D/Dachluefter-Gehaeuse.scad

$fn=36;

Bi=25; // Breite innen
Li=70; // Länge innen
Hi=20; // Höhe innen
W=1.2; // Wandstärke
R=1.5; // Abrundung Außenkanten

La=Li+2*W-R;
Ba=Bi+2*W-R;
Ha=Hi+W-R/2;

//translate([0,0,1]) cube([La,Ba,2], center=true);

render()
difference() {
  union() {
    hull() {
      translate([La/2, Ba/2, 0]) cylinder(d=R, h=1);
      translate([La/2, -Ba/2, 0]) cylinder(d=R, h=1);
      translate([-La/2, Ba/2, 0]) cylinder(d=R, h=1);
      translate([-La/2, -Ba/2, 0]) cylinder(d=R, h=1);

      translate([La/2, Ba/2, Ha]) sphere(d=R);
      translate([La/2, -Ba/2, Ha]) sphere(d=R);
      translate([-La/2, Ba/2, Ha]) sphere(d=R);
      translate([-La/2, -Ba/2, Ha]) sphere(d=R);
    }

    #hull() {
      for(i=[0,180]) rotate([0,0,i]) translate([(La+12)/2,0,0]) cylinder(d=10, h=4);
      H=8; translate([0,0,H/2]) cube([70, 20, H], center=true);
    }
  }

  translate([0,0,Hi/2]) cube([Li, Bi, Hi], center=true);

  for(i=[0,180]) rotate([0,0,i]) translate([(La+12)/2,0,0]) union() {
    cylinder(d=4, h=10, center=true);
    translate([0,0,3]) cylinder(r=5.6/sqrt(3), h=20, $fn=6, center=false);
  }
  translate([18,0,0]) union() {
    // Schalter
    cube([19.6, 13.2, 90], center=true);
    // Platine
    translate([-40,0,0]) cylinder(d=7, h=90, center=true);
  }

}